MacPeople 1997 August 15/MACPEOPLE-1997-08-15.ISO.7z/MACPEOPLE-1997-08-15.ISO/アップル関連/Open Transport⁄PPP 1.0/CCL Disk/Modem CCLs/HUCOM EX⁄V34ESII⁄V34ESCardSJ/HUCOM EX_V34ESII_V34ESCardSJ

Text File | 1996-12-02 | 10.1 KB | 542 lines

! HUCOM-EX336 / HUCOM-EX / HUCOM Simple 288 / HUCOM V34ESII
! HUCOM-V34ESCardSJ CCL File Original Version.
! for ARA2.0J & 2.1J and OT-PPP
!
!    Created by kan Kobayashi , HUCOM Inc.  in Nov.1996.
!
!  'mlts' resource info for this modem:
!    byte 1 == 01 -> modem HAS builtin reliability protocols
!    byte 2 == 01 -> reserved by Apple
!    byte 3 == 36 -> max hex chars in varstr 7 (54 dec)
!    byte 4 == 36 -> max hex chars in varstr 8
!    byte 5 == 36 -> max hex chars in varstr 9
!
@ORIGINATE
@ANSWER
!
! ---- Initial modem setup ----
!
! Set serial port speed depending upon the compression flag
!    A higher rate with compression on to handle expanded data from the modem
!    A lower rate closer to the DCE when compression is off
!
ifstr 5 1 "0"
serreset 115200, 0, 8, 1
hsreset 0 0 0 0 0 0
settries 0
jump 2
!
@LABEL 1
serreset 57600, 0, 8, 1
hsreset 0 0 0 0 0 0
settries 0
!
@LABEL 2
matchclr
matchstr 1 3 "OK¥13¥10"
! &F  - recall factory settings
! &D2 - DisConnect Modem on On-to-Off DTR transitions
! W2S95=40  - Connect result code reports modem speed and protocol and compression
! S0=0 - Don't answer calls
! E0   - Turn command echo off
!write "AT&F¥¥N0&D2W2S95=40S0=0S210=5E0¥13"
write "AT&F¥¥N0&D2W2S95=40S0=0E0¥13"
matchread 30
inctries
iftries 2 71
!
! Reset the Modem
!
DTRSet
pause 5
DTRClear
pause 5
DTRSet
flush
jump 2
!
@LABEL 3
! Modem responding & configured.
! determine if reliable link is requested.
!
! if modem mnp link requested (var 4 == 2) then jump label 4
ifstr 4 4 "2"
!
! if modem v42 link requested (for PPP) (var 4 == 1) then jump label 5
ifstr 4 5 "1"
!
! if no modem v42 link requested (var 4 == 0) [same as ARA 1.0] then jump label 9
ifstr 4 9 "0"
!
! else invalid value in var 4; exit w/error
jump 76
!
@LABEL 4
!  yes, MNP link is requested.  OK for MNP4 -> normal mode
matchclr
matchstr 1 7 "OK¥13¥10"
write "AT¥¥N3%C0S48=128¥13"
matchread 30
jump 71
!
@LABEL 5
! yes, v42 link is requested.
matchclr
matchstr 1 7 "OK¥13¥10"
write "AT¥¥N3%C0¥13"
matchread 30
jump 71
!
@LABEL 7
! if we DID want v42b in the modem, this is where it would go,
! but since the cpu does a better job at compressing compressable
! files, this setup stuff is commented out.  the matchstrings and
! associated labels have been left in.
!
ifstr 5 9 "0"
matchclr
matchstr 1 9 "OK¥13¥10"
write "AT%C3¥13"
matchread 30
jump 71
!
!
@LABEL 9
! If speaker on flag is true, jump to label 13.  Else turn off the speaker.
ifstr 2 13 "1"
pause 5
matchclr
matchstr 1 13 "OK¥13¥10"
write "ATM0L0¥13"
matchread 30
jump 71
!
! modem ready, so enable answering or originate a call - label range is 11-30
!
@LABEL 13
pause 5
ifANSWER 62
!
! if normal dialing (parm 6 == 0) jump to 19
ifstr 6 19 "0"
!
! if blind dialing (parm 6 == 1) jump to 17
ifstr 6 17 "1"
!
! if manual dialing (parm 6 == 2) jump to 15
ifstr 6 15 "2"
!
! else invalid value in var 6; exit w/error
jump 76
!
@LABEL 15
! Display ASK dialog with message.  Goto label 107 if dialog canceled.
ASK 2 "手動でダイヤルしたら、[OK]をクリックしてください。" 79
!ASK 2 "Pick up the phone & dial ^1.  Hit OK when the phone rings, then hangup." 79
note "ダイアル中。" 3
!note "Manual dialing initiated" 3
! X1 to ignore dialtone & busy, D to dial, ¥^ generates data tone
write "ATX1D¥^¥13"
jump 32
!
@label 17
note "ダイアルトーンを無視してダイアル中。" 3
!note "Dialing without tone" 3
matchclr
matchstr 1 19 "OK¥13¥10"
! X1 to ignore dialtone & busy for blind dialing
write "ATX3¥13"
matchread 30
jump 71
!
@label 19
! this is where we break up long dialstrings
!
! parm 1 is always the full dialstring from the conn doc
note "^1 をダイアル中。" 3
!note "Dialing ^1" 3
! parm 3 is always "p" for pulse & "t" for tone
!
! if parm 8 == blank (complete dialstring in parm 7)
!  then jump to label 27 & dial parm 7
ifstr 8 27 " "
!
! if parm 9 == blank (complete dialstring in parms 7 & 8)
!  then jump to label 24 & dial parm 7 & 8
ifstr 9 24 " "
!
!  else dial parm 7 & 8 & 9 (complete dialstring in parms 7, 8 & 9)
matchclr
matchstr 1 21 "OK¥13¥10"
! parm 7 holds first string fragment
write "ATD^3^7;¥13"
matchread 400
! modem not responding; bailout.
jump 71
@label 21
! parm 8 holds second string fragment
matchclr
matchstr 1 22 "OK¥13¥10"
write "ATD^3^8;¥13"
matchread 400
! modem not responding; bailout.
jump 71
@label 22
! parm 9 holds last string fragment
write "ATD^3^9¥13"
jump 32
!
@label 24
matchclr
matchstr 1 25 "OK¥13¥10"
! parm 7 holds first string fragment
write "ATD^3^7;¥13"
matchread 400
! modem not responding; bailout.
jump 71
@label 25
! parm 8 holds last string fragment
write "ATD^3^8¥13"
jump 32
!
@label 27
! parm 7 holds entire string
write "ATD^3^7¥13"
jump 32
!
!    connecting - label range is 31-60
!
@LABEL 32
matchclr
!
matchstr 1  34 "CONNECT 1200¥13¥10"
matchstr 2  35 "CONNECT 2400¥13¥10"
matchstr 3  36 "CONNECT 4800¥13¥10"
matchstr 4  37 "CONNECT 7200¥13¥10"
matchstr 5  38 "CONNECT 9600¥13¥10"
matchstr 6  39 "CONNECT 12000¥13¥10"
matchstr 7  40 "CONNECT 14400¥13¥10"
matchstr 8  41 "CONNECT 16800¥13¥10"
matchstr 9  42 "CONNECT 19200¥13¥10"
matchstr 10 43 "CONNECT 21600¥13¥10"
matchstr 11 44 "CONNECT 24000¥13¥10"
matchstr 12 45 "CONNECT 26400¥13¥10"
matchstr 13 46 "CONNECT 28800¥13¥10"
matchstr 14 47 "CONNECT 31200¥13¥10"
matchstr 15 48 "CONNECT 33600¥13¥10"
!
matchstr 16 68 "RING¥13¥10"
matchstr 17 72 "NO DIALTONE¥13¥10"
matchstr 18 73 "NO CARRIER¥13¥10"
matchstr 19 73 "ERROR¥13¥10"
matchstr 20 74 "BUSY¥13¥10"
matchstr 21 75 "NO ANSWER¥13¥10"
matchstr 22 77 "DELAYED"
matchstr 23 78 "BLACKLISTED"
!
matchstr 24 54 "PROTOCOL: NONE¥13¥10"
matchstr 25 55 "PROTOCOL: ALT¥13¥10"
matchstr 26 56 "PROTOCOL: LAP-M¥13¥10"
matchstr 27 57 "PROTOCOL: ALT - CELLULAR¥13¥10"
!
matchstr 28 51 "COMPRESSION: NONE¥13¥10"
matchstr 29 52 "COMPRESSION: V.42BIS¥13¥10"
matchstr 30 53 "COMPRESSION: CLASS 5¥13¥10"
!
matchstr 31 91 "CONNECT 1200TX/75RX¥13¥10"
!
matchread 700
ifANSWER 32
jump 71
!
!
@LABEL 34
note "1200 bps で接続中" 2
!note "Communicating at 1200 bps." 2
CommunicatingAt 1200
jump 58
!
@LABEL 35
note "2400 bps で接続中" 2
!note "Communicating at 2400 bps." 2
CommunicatingAt 2400
jump 58
!
@LABEL 36
note "4800 bps で接続中" 2
!note "Communicating at 4800 bps." 2
CommunicatingAt 4800
jump 58
!
@LABEL 37
note "7200 bps で接続中" 2
!note "Communicating at 7200 bps." 2
CommunicatingAt 7200
jump 58
!
@LABEL 38
note "9600 bps で接続中" 2
!note "Communicating at 9600 bps." 2
CommunicatingAt 9600
jump 58
!
@LABEL 39
note "12 kbps で接続中" 2
!note "Communicating at 12000 bps." 2
CommunicatingAt 12000
jump 58
!
@LABEL 40
note "14.4 kbps で接続中" 2
!note "Communicating at 14400 bps." 2
CommunicatingAt 14400
jump 58
!
@LABEL 41
note "16.8 kbps で接続中" 2
!note "Communicating at 16800 bps." 2
CommunicatingAt 16800
jump 58
!
@LABEL 42
note "19.2 kbps で接続中" 2
!note "Communicating at 19200 bps." 2
CommunicatingAt 19200
jump 58
!
@LABEL 43
note "21.6 kbps で接続中" 2
!note "Communicating at 21600 bps." 2
CommunicatingAt 21600
jump 58
!
@LABEL 44
note "24 kbps で接続中" 2
!note "Communicating at 24000 bps." 2
CommunicatingAt 24000
jump 58
!
@LABEL 45
note "26.4 kbps で接続中" 2
!note "Communicating at 26400 bps." 2
CommunicatingAt 26400
jump 58
!
@LABEL 46
note "28.8 kbps で接続中" 2
!note "Communicating at 28800 bps." 2
CommunicatingAt 28800
jump 58
!
@LABEL 47
note "31.2 kbps で接続中" 2
!note "Communicating at 31200 bps." 2
CommunicatingAt 31200
jump 58
!
@LABEL 48
note "33.6 kbps で接続中" 2
!note "Communicating at 33600 bps." 2
CommunicatingAt 33600
jump 58
!
! V42bis Link Connections.
! userhook 3 tells ARA that a modem to modem compression protocol has been negotiated
!
@LABEL 51
! No Compression.
jump 32
!
@LABEL 52
! V42bis Compression.
userhook 3
jump 32
!
@LABEL 53
! MNP5 Compression.
userhook 3
jump 32
!
!
! V.42 link connections.
! Tell ARA with USERHOOK 2 that a reliable modem link has been established.
!
@LABEL 54
jump 32
!
@LABEL 55
note "MNP リンクが成立。" 2
!note "MNP reliable link established." 2
userhook 2
jump 32
!
@LABEL 56
note "LAP-M リンクが成立。" 2
!note "LAP-M reliable link established." 2
userhook 2
jump 32
!
@LABEL 57
note "MNP 10 リンクが成立。" 2
!note "MNP10 reliable link established." 2
userhook 4
jump 32
!
@LABEL 58
! set the serial port handshake options for CTS
HSReset 0 1 0 0 0 0
!
! Connection established. In ORIGINATE mode pause before exit.
!
ifANSWER 59
pause 30
@LABEL 59
exit 0
!
! @ANSWER
! Set the modem to answer on 1st ring - label range is 61-70
!
@LABEL 62
ifstr 4 63 "1"
! for ARA
matchclr
matchstr 1 32 "OK¥13¥10"
write "AT¥¥N3S48=128S0=2¥13"
matchread 30
jump 71
!
!
@LABEL 63
! for OT-PPP (V.42)
matchclr
matchstr 1 32 "OK¥13¥10"
write "ATS0=2¥13"
matchread 30
jump 71
!
!
@LABEL 68
ifORIGINATE 32
! claim the serial port
userhook 1
note "電話に応対しています。" 2
!note "Answering phone..." 2
jump 32
!
!
! error messages - label range is 71-90
!
! Modem Not Responding
@LABEL 71
exit -6019
!
! No Dial Tone
@LABEL 72
exit -6020
!
! No Carrier or Error
@LABEL 73
exit -6021
!
! Busy
@LABEL 74
exit -6022
!
! No Answer
@LABEL 75
exit -6023
!
! Invalid Varstring Value
@LABEL 76
exit -6027
!
! DELAYED
@LABEL 77
exit -6022
!
! BLACKLISTED
@LABEL 78
exit -6022
!
! User Cancellation
@LABEL 79
exit -6008
!
! On Hook Modem
@LABEL 91
note "先方が電話を切りました。" 2
!note "Disconnecting phone..." 2
matchclr
matchstr 1 92 "OK¥13¥10"
pause 10
write "+++"
matchread 15
!
@LABEL 92
matchclr
matchstr 1 73 "NO CARRIER¥13¥10"
matchstr 2 73 "OK¥13¥10"
matchstr 3 73 "ERROR¥13¥10"
pause 3
write "ATH¥13"
matchread 30
jump 91
!
!
! Hang up the modem - label range is 101-120
!
@HANGUP
@LABEL 102
settries 0
HSReset 0 0 0 0 0 0
!
@LABEL 105
!
! Try to get control of the modem.
!
matchclr
matchstr 1 108 "OK¥13¥10"
pause 10
write "+++"
matchread 15
!
@LABEL 108
!-------------------
! secondly try ATH
!-------------------
matchclr
matchstr 1 111 "NO CARRIER¥13¥10"
matchstr 2 111 "OK¥13¥10"
matchstr 3 111 "ERROR¥13¥10"
pause 3
write "ATH¥13"
matchread 30
inctries
iftries 3 71
!---------------------------------------
! finaly try On-to-Off DTR transitions
!---------------------------------------
DTRSet
pause 5
DTRClear
pause 5
DTRSet
flush
jump 105
!
! recall the factory settings.
!
@LABEL 111
pause 15
matchclr
matchstr 1 114 "OK¥13¥10"
write "AT&F&D2S0=0¥13"
matchread 30
jump 71
!
@LABEL 114
exit 0
!
! labels 121-128 are reserved for future emergency hacks
!